Subalgebras of su(d)

This section describes functions for studying irreducible simple subalgebras of the Lie algebra su(d) (cf. [Dyn57]). The verbose flag "SubSU" may be set to show details and progress of the various computations.

The algorithms and the implementation in this package are due to Robert Zeier. For more information about some of the algorithms used and the results obtained using this package we refer to [ZSH11].

IrreducibleSimpleSubalgebrasOfSU(N) : RngIntElt -> SeqEnum

A list of all irreducible simple subalgebras occurring in the Lie algebra su(d), for 2 ≤d ≤N.

IrreducibleSimpleSubalgebraTreeSU(Q, d) : SeqEnum[SeqEnum[Tup]], RngIntElt -> GrphDir

The subalgebra tree for degree d as a directed graph whose vertex labels describe subalgebras, derived from the list Q of irreducible subalgebras. The vertex labels are records with three fields: algebra, a string containing the Cartan type of this subalgebra; weights, a sequence of highest weights (as sparse vectors) corresponding to irreducible representations (they are related by an outer automorphism if there is more than one highest weight); and type, an integer with values -1, 1, or 0 corresponding to irreducible representations of quaternionic, real, or complex type, respectively (the Frobenius-Schur indicator).

PrintTreesSU(Q, F) : SeqEnum[SeqEnum[Tup]], MonStgElt ->

    FromDegree: RngIntElt               Default: 2

    ToDegree: RngIntElt                 Default: |Q|

    IncludeTrivial: BoolElt             Default: true

Print the tree of subalgebras in the sequence Q (as obtained by a call to IrreducibleSimpleSubalgebrasOfSU) to the file with filename F. The file F will be overwritten.

The resulting file will be a LaTeX document that may be typeset using latex followed by dvipdf, for instance. If the resulting file is large, the main memory allocated to TeX may have to be increased (the main_memory directive in texmf.cnf). Contact your system administrator in case of difficulty.

The optional arguments FromDegree and ToDegree limit which degrees are output; IncludeTrivial may be set to false to remove "trivial" cases (i.e. trivial trees) from the output. For d ≥5 and d even, su(d) is considered trivial if it contains only the (proper) irreducible simple subalgebras C_d/2 (i.e. sp(d/2)), D_d/2 (i.e. so(d)), and A₁ (i.e. su(2)); for d ≥5 and d is odd, su(d) is considered trivial if it contains only B_{(d - 1)/2} (i.e. so(d)) and A₁.

The Lie algebras in the output are coloured according to type: red for -1, blue for 1, and black for 0 (see IrreducibleSimpleSubalgebraTreeSU).

> Q := IrreducibleSimpleSubalgebrasOfSU(2^10);
> t := IrreducibleSimpleSubalgebraTreeSU(Q, 12);
> t;
Digraph
Vertex  Neighbours
1       2 4 ;
2       3 ;
3       ;
4       ;
> r := VertexLabel(t, 1); r`algebra;
rec<recformat<algebra: MonStgElt, weights, type: IntegerRing()> | 
    algebra := A11,
    weights := [
        Sparse matrix with 1 row and 11 columns over Integer Ring,
        Sparse matrix with 1 row and 11 columns over Integer Ring
    ],
    type := 0>
> r := VertexLabel(t, 2); r;
rec<recformat<algebra: MonStgElt, weights, type: IntegerRing()> | 
    algebra := C6,
    weights := [
        Sparse matrix with 1 row and 6 columns over Integer Ring
    ],
    type := -1>
> [ Matrix(w) : w in r`weights ];
[
    [1 0 0 0 0 0]
]
> RepresentationDimension(RootDatum("C6"),[1,0,0,0,0,0]); 
12
> r := VertexLabel(t, 3); r`algebra;
A1
> [ Matrix(w) : w in r`weights ];
[
    [11]
]
> RepresentationDimension(RootDatum("A1"),[11]);
12
> r := VertexLabel(t, 4); r`algebra;
D6

> V := RSpace(Integers(), 6);
> [ RepresentationDimension(RootDatum("C6"), v) : v in Basis(V) ];
[ 12, 65, 208, 429, 572, 429 ]

> [ i : i in [2..2^10] | exists{r : r in VertexLabels(
>    IrreducibleSimpleSubalgebraTreeSU(Q, i)) | r`algebra eq "C6"} ];
[ 12, 65, 78, 208, 364, 429, 560, 572 ]
> t := IrreducibleSimpleSubalgebraTreeSU(Q, 78);
> l := VertexLabels(t);
> [ r`algebra : r in l ];
[ A77, C39, A1, D39, B6, C6, E6, A2, A11, A12 ]
> r := l[6];
> [ Matrix(x) : x in r`weights ];
[
    [2 0 0 0 0 0]
]