Representations of an Automorphism Group

To compute with automorphism groups, Magma uses various concrete representations of the group. These are summarised in this section.

PermutationRepresentation(A) : GrpAuto -> Map, GrpPerm, SetIndx

Construct a permutation representation of the group of automorphisms A. The function finds a union of conjugacy classes of the base group G which is closed under the action of A and with G-normal closure equal to G. The permutation action of A on such a set is faithful. The results returned are the representation of A as a homomorphism A to P, the image of this homomorphism as a permutation group with standard support, and the set of elements of G used.

PermutationGroup(A) : GrpAuto -> GrpPerm

Given a group of automorphisms A of a group G, this function returns a permutation group isomorphic to A as defined in the description of the function PermutationRepresentation.

PermutationSupport(A) : GrpAuto -> SetIndx

Given a group of automorphisms A of a group G, this function returns the set of elements of G (i.e., a union of conjugacy classes) used as the support of the permutation group constructed by the PermutationRepresentation function.

PCGroupAutomorphismGroupPGroup(A) : GrpAuto -> BoolElt, Map, GrpPC

Attempt to directly construct a pc-representation for the group of automorphisms A of a conditioned p-group G. A must have been constructing using the AutomorphismGroup intrinsic, or any equivalent alias. The results returned are a boolean value indicating the solubility of A, and if soluble, a representation of A as a homomorphism A to P and the image of this homomorphism as a pc-group.

FPGroup(A) : GrpAuto -> GrpFP, Map

A presentation for the group of automorphisms A on the generators of A. The isomorphism from the finitely presented group to the group of automorphisms A is also returned.

OuterFPGroup(A) : GrpAuto -> GrpFP, Map

Suppose that A is the full group of automorphisms of a group G. This function returns a finitely presented group O isomorphic to the outer automorphism group of the base group G. The natural homomorphism from FPGroup(A) onto O is also returned.

> G := PGL(2, 9);
> A := AutomorphismGroup(G);
> PermutationGroup(A);
Permutation group acting on a set of cardinality 36
Order = 1440 = 2^5 * 3^2 * 5
    (1, 30)(3, 27)(5, 17)(6, 24)(8, 9)(10, 14)(11, 13)(12, 32) (15, 34)(16, 21)
       (18, 25)(19, 28)(22, 29)(23, 31)(26, 33)(35, 36)
    (1, 32, 19, 22)(2, 34)(3, 18, 7, 17)(4, 25, 30, 31) (5, 23, 33, 24)
       (6, 15, 26, 21)(8, 16, 29, 20)(9, 35, 14, 27) (10, 13, 11, 12)(28, 36)
    (1, 2, 3, 5, 8, 13, 22, 31)(4, 7, 9, 15, 24, 26, 34, 29)
       (6, 10, 17, 23, 32, 33, 28, 35)(11, 19, 27, 16, 25, 21, 30, 36)
       (12, 20, 14, 18)
    (1, 32, 33, 12, 21, 6)(2, 34, 26, 35, 17, 16)(3, 28, 22, 7, 18, 13)
       (4, 31, 20, 29, 24, 11)(5, 19, 25, 10, 15, 8)(9, 30, 36, 14, 23, 27)
> F<x, y, z, t> := FPGroup(A);
> F;
Finitely presented group F on 4 generators
Relations
    x^2 = Id(F)
    y^4 = Id(F)
    (x * y^-1)^5 = Id(F)
    y^-2 * x * y^-2 * x * y^-2 * x * y^2 * x * y^2 * x = Id(F)
    z^-1 * x * z * y^-1 * x^-1 * y^-2 * x^-1 * y * x^-1 * 
       y^-2 * x^-1 * y * x^-1 * y^-1 * x^-1 = Id(F)
    z^-1 * y * z * y * x^-1 * y * x^-1 * y^-1 * x^-1 = Id(F)
    z^2 * y^-1 * x^-1 * y * x^-1 * y^-1 * x^-1 = Id(F)
    x^t = y * x * y^-1
    y^t = y^-1 * x * y * x * y
    z^t = z * x * y^-1 * x
    t^2 = x * y^2 * x * y^-1 * x * y

> load hs100;
Loading "/home/magma/libs/pergps/hs100"
The simple group of Higman-Sims represented as a
permutation group of degree 100. 
Order: 44 352 000 = 2^9 * 3^2 * 5^3 * 7 * 11. 
Base: 1, 2, 3, 4, 5, 6. 
Group: G
> aut := AutomorphismGroup(G);
> P := PermutationGroup(aut);
> P;
Permutation group P acting on a set of cardinality 5775
Order = 88704000 = 2^10 * 3^2 * 5^3 * 7 * 11

> lix := LowIndexSubgroups(P, 100);
> [ Index(P, H) : H in lix];
[ 1, 2, 100 ]

> H := CosetImage(P, lix[3]);
> H;
Permutation group H acting on a set of cardinality 100
> CompositionFactors(H);
    G
    |  Cyclic(2)
    *
    |  HS
    1