Example GrpMatGen_RationalMatrixGroupDatabase (H66E12)

> DB := RationalMatrixGroupDatabase();
> G := Group(DB, 12, 3);
> FactoredOrder(G);
[ <2, 17>, <3, 8>, <5, 2> ]
> CompositionFactors(G);
    G
    |  Cyclic(2)
    *
    |  Cyclic(2)
    *
    |  C(2, 3)                = S(4, 3)
    *
    |  Cyclic(2)
    *
    |  Cyclic(2)
    *
    |  C(2, 3)                = S(4, 3)
    *
    |  Cyclic(2)
    1

> time cl := Classes(G);
Time: 18.580
> #cl;
1325

Conjugacy in Classical Groups

According to Kleidman and Liebeck [KL90] a group G is a finite classical group if Ω⊆G⊆A or /line(Ω)⊆G⊆/line(A), where Ω and A are given by the following table and where the symbols /line(Ω) and /line(A) denote the groups Ω and A modulo scalars.

   type        Omega        Delta     A
   ----------------------------------------------
   linear      SL(n,q)      GL(n,q)   GammaL*(n,q)
   symplectic  Sp(n,q)      CSp(n,q)  GammaSp(n,q)
   unitary     SU(n,q)      CU(n,q)   GamaU(n,q)
   orthogonal  Omega^e(n,q) CO^e(n,q) GammaO^e(n,q)
   ------------------------------------------------

The groups in the last three rows of column Δ are the so-called conformal groups; they are the groups A∩GL(n, q) which preserve an alternating, hermitian or quadratic form up to a scalar multiple.

Important examples of classical groups, which in general are in neither column Ω nor column Δ, are the general orthogonal groups GO^ε(n, q), which preserve a quadratic form. In magma these are the groups GO(n,q), GOPlus(n,q) or GOMinus(n,q) where ε is respectively 0, + or -.

As described in the documentation for the ConjugacyClasses intrinsic, magma constructs the classes by computing a complete collection of invariants and then determining a representative matrix for each invariant or by using the algorithms described in [Fra20].

The intention is to implement this for all groups G such that Ω⊆G⊆Δ. Currently this implementation is invoked automatically when constructing the conjugacy classes for G such that SL(n, q)⊆G⊆GL(n, q), the symplectic groups G = Sp(2n, q), the unitary groups SU(n, q)⊆G⊆GU(n, q), the conformal unitary groups CU(n, q) and the orthogonal groups Ω^ε(n, q), SO^ε(n, q) and GO^ε(n, q) where ε is 0, + or -. In addition, when q is odd, it is invoked for the conformal groups symplectic groups CSp(2n, q) and the conformal orthogonal groups CO^ε(n, q)

The implementation is based on Milnor [Mil69] combined with the fundamental work of Wall [Wal63] as interpreted in Gonshaw, Liebeck and O'Brien [GLO17] and the theses of Fulman [Ful97], Britnell [Bri03] and De Franceschi [Fra18], [Fra20].

Class invariants. The conjugacy classes in the group GL(n, q) are parametrised by sequences of pairs < f, μ(f) > where f is an irreducible polynomial and μ(f) is a partition such that

∑_fdeg(f)|μ(f)| = n.

In the following description a partition of an integer n will be represented either by a sequence [λ₁, λ₂, ..., λ_r] such that λ₁≥λ₂≥ ... ≥λ_r and n= ∑_i=1^rλ_i or by the sequence of multiplicities [< 1, m₁ >, < 2, m₂ >, ..., < n, m_n >], omitting the terms with m_i = 0, where n = ∑_i=1ⁿ im_i.

For the conjugacy classes of the classical groups there are restrictions on the polynomials and partitions that can occur.

If f(t)∈k[t] is a polynomial of degree d (over a field k) such that f(0)≠0, the dual of f(t) is the polynomial f ^* (t) = f(0) ^{- 1}t^df(t ^{- 1}).

A polynomial f(t) is *-symmetric if f ^* (t) = f(t); it is *-irreducible if it has no proper *-symmetric factors.

DualPolynomial(f) : RngUPolElt -> RngUPolElt

The dual of the polynomial f.

StarIrreduciblePolynomials(F,d) : FldFin, RngIntElt -> SeqEnum

The sequence of all *-irreducible polynomials of degree d with coefficients in F.

Symplectic groups. If g∈Sp(2n, q), then g preserves a non-degenerate alternating form and from this it follows that the minimal polynomial of g is *-symmetric. A symplectic signed partition of an integer n is a sequence [< 1, m₁ >, < pm2, m₂ >, ..., < n, m_n >], such that the unsigned sequence [< 1, m₁ >, < 2, m₂ >, ..., < n, m_n >] is a partition of n, where m_i is even for all odd i. Only the terms < i, m_i > where i is even are signed.

The conjugacy classes of Sp(2n, q) are in one-to-one correspondence with sequences of pairs < f, μ(f) >, where f is a *-irreducible polynomial and μ(f) is a partition if deg (f) > 1 and a symplectic signed partition if deg(f) = 1. (Note that t - 1 and t + 1 are the only *-irreducible polynomials of odd degree.) When q is a power of 2, more elaborate labels are needed to distinguish the conjugacy classes.

After invoking the command cc := Classes(G); the conjugacy classes for of the group G will be returned as the value of cc and assigned to G`Classes. In addition, the labels for the conjugacy classes will be assigned either to G`Labels_S or G`Labels_A (or both). These labels are used internally.

Conformal symplectic groups. If g belongs to the conformal symplectic group C over the field F there is a non-zero element φ∈F such that gJg^(sevenrm tr) = φ J, where J is the matrix of the alternating form preserved by C. In this case the minimal polynomial of g is φ-symmetric in the sense of the following definition.

Given φ∈F ^x and a polynomial f(t) of degree d such that f(0)≠0, the φ-dual of f(t) is

f^[φ](t) = f(0) ^{- 1}t^d f(φ t ^{- 1}).

The polynomial f(t) is φ-symmetric if f^[φ](t) = f(t). Thus f(t) is φ-symmetric if and only if t^d f(φ t ^{- 1}) = f(0)f(t). For example t² - φ and t² + φ are φ-symmetric and if φ = λ², then t - λ and t + λ are φ-symmetric.

A polynomial f(t) is φ-irreducible if it is φ-symmetric and has no proper φ-symmetric factors.

PhiDual(f,phi) : RngUPolElt -> RngUPolElt

The φ-dual of the polynomial f.

PhiIrreduciblePolynomials(F,d) : FldFin, RngIntElt -> SeqEnum[Tup]

The sequence of pairs < φ, pols > where pols is the sequence of all monic polynomials of degree d over the field F with no proper φ-symmetric factor and φ runs through the non-zero elements of F.

Each conjugacy class of CSp(2n, q) will be represented by a pair < φ, Ξ >, where φ∈F ^x and Ξ is an indexed set of pairs < f, μ >, where f is a φ-irreducible polynomial and μ is either a partition or, in the case that f divides t² - φ, a symplectic signed partition. That is, a conjugacy class invariant has the form < φ, {@ < f₁, μ₁ >, < f₂, μ₂ >, ... @} >.

Extended symplectic groups. A group G is an extended symplectic group if Sp(n, q)⊆G ⊆CSp(n, q).

ExtendedSymplecticGroup(n,q,m) : RngIntElt, RngIntElt, RngIntElt -> GrpMat

ExtendedSp(n,q,m) : RngIntElt, RngIntElt, RngIntElt -> GrpMat

The subgroup of CSp(n, q) that contains Sp(n, q) as a subgroup of index m.

IndexOfSp(G) : GrpMat -> RngIntElt

The index of the symplectic group in G. This function fails with a runtime exception if G is not an extended symplectic group.

Unitary groups. If f(t)∈k[t] is a polynomial of degree d (over a field k with an automorphism x |-> /line x where x≠/line(x) and /line(/line(x)) = x) such that f(0)≠0, the twisted dual of f(t) is the polynomial f^~(t) = /line(f(0)) ^{- 1}t^d /line(f)(t ^{- 1}).

A polynomial f(t) is tilde-symmetric if f^~(t) = f(t); it is tilde-irreducible if it has no proper tilde-symmetric factors. If g∈GU(n, q), then g preserves a non-degenerate hermitian form and from this it follows that the minimal polynomial of g is tilde-symmetric with respect to the automorphism x |-> x^q of GF(q²).

TildeDualPolynomial(f) : RngUPolElt -> RngUPolElt

The twisted dual of the polynomial f.

TildeIrreduciblePolynomials(q,d) : RngIntElt, RngIntElt -> SeqEnum

The sequence of all tilde-irreducible polynomials of degree d with coefficients in GF(q²).

The conjugacy classes of GU(n, q) are in one-to-one correspondence with sequences of pairs < f, μ(f) >, where f is a tilde-irreducible polynomial and μ(f) is a partition, written as a sequence of multiplicities < i, m_i >.

Extended special unitary groups. A group G is an extended special unitary group of index m if SU(n, q)⊆G ⊆GU(n, q) and m = |G : SU(n, q)|.

ExtendedSpecialUnitaryGroup(n,q,m) : RngIntElt, RngIntElt, RngIntElt -> GrpMat

ExtendedSU(n,q,m) : RngIntElt, RngIntElt, RngIntElt -> GrpMat

The subgroup of GU(n, q) that contains SU(n, q) as a subgroup of index m.

IndexOfSU(G) : GrpMat -> RngIntElt

The index of the special unitary group in G. This function fails with a runtime exception if G is not an extended special unitary group.

Orthogonal groups. An orthogonal signed partition of an integer n is a sequence

[< ∓ 1, m₁ >, < 2, m₂ >, ..., < n, m_n >],

such that the unsigned sequence [< 1, m₁ >, < 2, m₂ >, ..., < n, m_n >] is a partition of n (in multiplicity format), where m_i is even for all even i. Only the terms < i, m_i > where i is odd are signed.

The conjugacy classes of GO^ε(n, q) are in one-to-one correspondence with sequences of pairs < f, μ(f) >, where f is a *-irreducible polynomial and μ(f) is a partition if deg (f) > 1 and an orthogonal signed partition if deg(f) = 1. (Note that t - 1 and t + 1 are the only *-irreducible polynomials of odd degree.) When q is a power of 2, more elaborate labels are needed to distinguish the conjugacy classes.

Standard and natural classical groups.

Here we describe intrinsics to list conjugacy classes, determine centralisers, and decide conjugacy in the classical groups. The classes are listed using algorithms developed and implemented by De Franceschi [Fra18], [Fra20], Gonshaw, Liebeck and O'Brien [GLO17], and Taylor. The algorithms to construct centralisers and decide conjugacy were developed and implemented by De Franceschi [Fra18], [Fra20], and De Franceschi, O'Brien and Liebeck [FLO25]. O'Brien and Taylor prepared the final versions of these functions for inclusion in Magma.

The functions listed below with arguments (type, d, q) refer to the `standard' classical groups: the groups returned by Magma functions such as GU(d,q) and so on. The accepted values for the argument (or parameter) type are the strings "SL", "GL", "Sp", "SU", "GU", "Omega+", "Omega-", "Omega", "SO+", "SO-", "SO", "GO+", "GO-",
and "GO".

The conjugates of these groups within the ambient general linear group are the `natural copy' classical groups. Those functions which accept as argument a group G can be applied to all such conjugates of the standard copy of G. The type of a standard or natural copy of G is returned by ClassicalGroupType.

ClassicalConjugacyClasses(G) : GrpMat -> SeqEnum, SetIndx

ClassicalClasses(G) : GrpMat -> SeqEnum, SetIndx

The sequence of conjugacy classes and the corresponding sequence of labels for the natural classical group G.

ClassicalConjugacyClasses(type,d,q) : MonStgElt, RngIntElt, RngIntElt -> SeqEnum, SetIndx

ClassicalClasses(type,d,q) : MonStgElt, RngIntElt, RngIntElt -> SeqEnum, SetIndx

The conjugacy classes and their labels for the standard classical group of the supplied type, rank d and field size q.

ClassicalCentralizer(G,g) : GrpMat, GrpMatElt -> GrpMat

The centralizer of g in the natural classical group G.

ClassicalCentraliserOrder(G,g) : GrpMat, GrpMatElt -> RngIntEltFact

The factored order of the centralizer of g in the natural classical group G.

ClassicalClassSize(G,g) : GrpMat, GrpMatElt -> RngIntElt

The size of the conjugacy class of g in the natural classical group G.

ClassicalIsConjugate(G,g,h) : GrpMat, GrpMatElt, GrpMatElt -> BoolElt, GrpMatElt

If g and h are conjugate in the natural classical group G, return true and a conjugating element, otherwise return false.

> G := OmegaPlus (16, 4);

> // some natural copy of the group 
> G := RandomConjugate (G);

> g := Random (G);

> z := ClassicalCentraliserOrder (G, g);

> C := ClassicalCentraliser (G, g);

> FactoredOrder (C) eq z;

true 

> g := Random (G);

> m := ClassicalClassSize (G, g);

> C := ClassicalCentraliser (G, g);
> #G div #C eq m;
true 

> x := Random (G);
> flag, c := ClassicalIsConjugate (G, g, g^x);
> g^c eq g^x;
true 

    type: MonStgElt                     Default: 

> G := SOPlus (6, 9);

> g := G.1^G.2;

> Cg := ClassicalCentraliser (G, g);

> #Cg;
728

> C := ClassicalClasses (G);
> phi := ClassicalClassMap (G);

> index := phi (g);
> index;
123 

> assert #G div C[index][2] eq #Cg;

> g := C[11][3]^G.1;
> h := C[12][3]^G.1;
> label_g := IsometryGroupClassLabel ("GO+", g);
> label_h := IsometryGroupClassLabel ("GO+", g);

> // are these elements conjugate in GO+?
> label_g eq label_h;
true 

> // are these elements conjugate in G?
> ClassicalIsConjugate (G, g, h);

false 
> 

> C, L := ClassicalClasses ("GO", 7, 9);
> L[4];
{*
    <0, $.1 + 1, {* <1, 1>^^5, <1, w> *}>,
    <0, $.1 + 2, {* <1, 1> *}>
*}
> G := GO(7, 9);
> phi := ClassicalClassMap (G, C, L);
> phi;
> X := {@ G.i^a * G.j^b: a in [1..Order (G.i)], b in [1..Order (G.j)],
>     i, j in [1..Ngens (G)] @};
> x := X[46];
> phi (x);
682 

> iseq := function(d,q)
>   G := Sp(d,q);
>   cc := ConjugacyClasses(G);
>   reps := [{ One(G) }];
>   labels := [{@ IsometryGroupClassLabel("Sp",One(G)) @}];
>   R := {c[3] : c in cc | c[1] eq 2};
>   T := &join[ Class(G,x) : x in R ];
>   L := {@ IsometryGroupClassLabel("Sp",t) : t in R @};
>
>   k := 1;
>   total := 1 + #R;
>   print "Layer", k, ":", #R;;
>
>   repeat
>     Append(~reps, R);
>     Append(~labels, L);
>     if total eq #cc then break; end if;
>     R := { };
>     L := {@  @};
>     k +:= 1;
>     for g in reps[k] do
>       for t in T do
>         h := g*t;
>         mu := IsometryGroupClassLabel("Sp",h);
>         if mu notin labels[k-1] and mu notin labels[k] and mu notin L then
>           Include(~R,h);
>           Include(~L, mu);
>           if total + #R eq #cc then break g; end if;
>         end if;
>       end for;
>     end for;
>     total +:= #R;
>     print "Layer", k, ":", #R;;
>   until IsEmpty(R);
>   return reps;
> end function;

> reps := iseq(4,3);
Layer 1 : 2
Layer 2 : 3
Layer 3 : 7
Layer 4 : 15
Layer 5 : 6

> H := SU(12, 9);
> // set up just unipotent classes 
> U := UnipotentClasses ("SU", 12, 9);
> #U;
88 
> C := ClassicalCentraliser (H, U[4][3]);
> FactoredOrder (C);
[ <2, 2>, <3, 28>, <5, 1> ]
> 
> K := Sp (6, 8);
> // set up just semisimple classes 
> S := SemisimpleClasses ("Sp", 6, 8);
> // for each semisimple class rep, construct all classes for that rep 
> G := Sp(6, 8);
> T := [ClassesForFixedSemisimple (G, S[i][3]): i in [1..#S]];
> // Total number of classes of K 
> &+[#x: x in T];
684 
> 
> // polynomial for number of classes in isometry group of this rank 
> f := IsometryGroupNumberOfClasses ("SpEven", 6);
> f;
q^3 + 2*q^2 + 5*q + 4
> Evaluate (f, 8);
684 

    UseLMGHom: BoolElt                  Default: false

    MatricesOnly: BoolElt               Default: false

> time cc, P, f, mm := ProjectiveClassicalClasses("SL",6,3);
Time: 0.150
> H := sub<Generic(P) | P>;
> time hh := Classes(H);
Time: 3.510
> P eq PSL(6,3);
true

> cc, P, f, mm := ProjectiveClassicalClasses("Sp",4,3);
> mm[4];
  <
     3,

     40,

     [1 0 0 0]
     [0 1 1 0]
     [0 0 1 0]
     [0 0 0 1]
  >
> cc[4][3] eq f(mm[4][3]);
true