Example ModSym_IntersectionPairing (H145E18)

In this example, we illustrate several basic properties of the intersection pairing on H₁(X₀(37), Z). First, let H37 be the space of modular symbols that corresponds to H₁(X₀(37), Z), and compute a basis for H37.

> M37 := ModularSymbols(37,2);
> H37 := CuspidalSubspace(M37);
> Z := IntegralBasis(H37); Z;
[
    {-1/29, 0},
    {-1/22, 0},
    {-1/12, 0},
    {-1/18, 0}
]

Now we compute some intersection numbers.

> IntersectionPairing(Z[1],Z[2]);
-1
> IntersectionPairing(Z[3],Z[4]);
0

The intersection pairing is perfect and skew-symmetric, so the matrix that defines it is skew-symmetric and has determinant ∓ 1 (in fact, it has determinant +1).

> A := MatrixAlgebra(RationalField(),4);
> I := A![IntersectionPairing(x,y) : x in Z, y in Z]; I;
[ 0  1  0  1]
[-1  0  1  1]
[ 0 -1  0  0]
[-1 -1  0  0]
> I + Transpose(I) eq 0;
true
> Determinant(I);
1

The Hecke operators are compatible with the intersection pairing in the sense that (T_n x, y) = (x, T_n y).

> T2 := HeckeOperator(M37,2);
> IntersectionPairing(Z[1]*T2,Z[2]);
1
> IntersectionPairing(Z[1],Z[2]*T2);
1

It is note the case (T_n x, T_n y) = (x, y) for all n, x, and y.

> IntersectionPairing(Z[1]*T2,Z[2]*T2);
-2

The existence of the intersection pairing implies that H₁(X₀(N), Z) is isomorphic, as a module over the Hecke algebra, to its linear dual Hom(H₁(X₀(N), Z), Z).

---

[Next][Prev] [Right] [Left] [Up] [Index] [Root]