Lie Algebras Generated by Extremal Elements

A non-zero element x of a Lie algebra L over the field K is extremal if [x, [x, y]] ∈K x for all y ∈L. If x is extremal, the existence of a linear map f_x : L -> K such that [x, [x, y]] = f_x(y) x for all y ∈L immediately follows from linearity of [., .].

In this section we describe functions for computing with Lie algebras generated by such extremal elements. For a simple connected undirected finite graph Γ we consider an algebraic variety X over K whose K-points parametrize Lie algebras generated by extremal elements. Here the generators of the Lie algebras correspond to the vertices of the graph, and we prescribe commutation relations corresponding to the nonedges of Γ.

Details of the setup may be found in [Roo11]; we describe the essential ingredients here.

Assume that Γ is a connected undirected finite graph with n vertices, without loops or multiple bonds, and that K is a field of characteristic distinct from 2. We let Π be the vertex set of Γ and denote adjacency of two vertices x, y ∈Π by i ~j.

We denote by F(K, Γ) the quotient of the free Lie algebra over K generated by Π modulo the relations [x, y]=0 for all x, y ∈Π with x not~y. We write F ^* for the space of all K-linear functions on F. For every f ∈(F ^* )^Π we denote by L(K, Γ, f) (often abbreviated to L(f)) the quotient of F(K, Γ) by the ideal I( f ) generated by the infinitely many elements [x, [x, y]] - f_x(y) x for x ∈Π, y ∈F.

By construction L( f ) is a Lie algebra generated by |Π| = n extremal elements, the extremal generators corresponding to the vertices of Γ and commuting whenever they are not adjacent. The element f_x ∈F ^* is a parameter expressing the extremality of x ∈Π.

In the Lie algebra L(0) the elements of Π map to sandwich elements. This algebra is finite-dimensional, by [ZK90] this Lie algebra is finite-dimensional; for general f ∈(F ^* )^Π we have dim(L(f)) ≤dim(L(0)) by [CSUW01, Lemma 4.3]. It is therefore natural to focus on the Lie algebras L( f ) of maximal possible dimension, i.e., those of dimension dim(L(0)). We define the set X := { f ∈(F ^* )^Π | dim(L(f)) = dim(L(0)) }, the parameter space for all maximal-dimensional Lie algebras of the form L( f ).

The functions currently implemented in Magma allow computation of X and L(f), for any f, for the cases where X is an affine space (which is unproven, but true in all currently known cases).

Lie algebras generated by extremal elements are of type AlgLieExtr. The verbose flag "AlgLieExtr" may be set between 1 and 5 to show details and progress of the various computations.

Constructing Lie Algebras Generated by Extremal Elements

ExtremalLieAlgebra(K, n) : Rng, RngIntElt -> AlgLieExtr

    CommGens: SeqEnum                   Default: []

    HeisenbergPairs: SeqEnum            Default: []

Construct the Lie algebra over the field K generated by n extremal elements. The characteristic of K must be distinct from 2.

The optional argument CommGens contains pairs of integers (i, j), with 1 ≤i, j ≤n, describing that generators x_i and x_j commute, i.e., [x_i, x_j] = 0.

The optional argument HeisenbergPairs contains pairs of integers (i, j), with 1 ≤i ≤n and 1 ≤j ≤dim(L(0)), describing that f_xi(b_j) should be taken equal to 0. (Note that if it is required to have j > n it would be necessary to have prior knowledge about the basis of L(0)).

ExtremalLieAlgebra(K, G) : Rng, GrphUnd -> AlgLieExtr

    HeisenbergPairs: SeqEnum            Default: []

Construct the Lie algebra over the field K whose extremal generators are described by the graph G, i.e., with |V(G)| generators, and x_i and x_j commute whenever vertices x_i and x_j of G are not adjacent.

See ExtremalLieAlgebra above for a description of the optional argument HeisenbergPairs.

Properties of Lie Algebras Generated by Extremal Elements

NumberOfGenerators(L) : AlgLieExtr -> RngIntElt

Ngens(L) : AlgLieExtr -> RngIntElt

The number of generators of L.

CoefficientRing(L) : AlgLieExtr -> Rng

BaseRing(L) : AlgLieExtr -> Rng

The coefficient ring of L. Immediately after construction, this is equal to the field K provided as argument to ExtremalLieAlgebra. However, after the multiplication table has been computed (see below), the coefficient ring would in general be a multivariate polynomial ring over K describing the parameter space.

CommutatorGraph(L) : AlgLieExtr -> GrphUnd

The graph describing the extremal generators of L and their commutator relations.

> QQ := Rationals();
> L := ExtremalLieAlgebra(QQ, BipartiteGraph(2,2));
> Ngens(L), CoefficientRing(L);
4 Rational Field
> G := CommutatorGraph(L); G;
Graph
Vertex  Neighbours

1       3 4 ;
2       3 4 ;
3       1 2 ;
4       1 2 ;

> L := ExtremalLieAlgebra(QQ, 4 : CommGens := [<1,2>,<3,4>]);
> Ngens(L), CoefficientRing(L);
4 Rational Field
> G := CommutatorGraph(L); G;
Graph
Vertex  Neighbours

1       3 4 ;
2       3 4 ;
3       1 2 ;
4       1 2 ;

> B, C := Basis(L); 
> B;
[
    $.1,
    $.2,
    $.3,
    $.4,
    ($.4, $.2),
    ($.4, $.1),
    ($.3, $.2),
    ($.3, $.1),
    ($.4, ($.3, $.2)),
    ($.4, ($.3, $.1)),
    ($.2, ($.4, $.1)),
    ($.2, ($.3, $.1)),
    ($.4, ($.2, ($.3, $.1))),
    ($.3, ($.2, ($.4, $.1))),
    ($.2, ($.4, ($.3, $.1)))
]
> [ c(["x","y","z","u"], func<i,j|i cat j>) : c in C ];
[ x, y, z, u, uy, ux, zy, zx, uzy, uzx, yux, yzx, uyzx, zyux, yuzx ]
> A := FreeAlgebra(Rationals(), 4);
> [ c([A.1,A.2,A.3,A.4], func<x,y|x*y>) : c in C ];
[
    $.1,
    $.2,
    $.3,
    $.4,
    $.4*$.2,
    $.4*$.1,
    $.3*$.2,
    $.3*$.1,
    $.4*$.3*$.2,
    $.4*$.3*$.1,
    $.2*$.4*$.1,
    $.2*$.3*$.1,
    $.4*$.2*$.3*$.1,
    $.3*$.2*$.4*$.1,
    $.2*$.4*$.3*$.1
]
> #B, #C, Dimension(L);
15 15 15

    HowMuch: MonStgElt                  Default: "Auto"

    MemLimit: RngIntElt                 Default: ∞

    FullJacobi: BoolElt                 Default: false

    Rep: MonStgElt                      Default: "Auto"

    Check: BoolElt                      Default: true

> L := ExtremalLieAlgebra(Rationals(), 3);
> L:Maximal;
Lie algebra generated by 3 extremal elements, defined over Rational 
Field
> MultiplicationTable(~L);
> L:Maximal;
Lie algebra generated by 3 extremal elements, originally defined over 
Rational Field
  Now living over Polynomial ring of rank 4 over Rational Field
  Dimension: 8
  Picked 4 f-values:
    f(2, [1]) = f21
    f(3, [1]) = f31
    f(3, [2]) = f32
    f(1, [32]) = f132

> Dimension(L);
8
> MT := MultiplicationTable(L);
> MT[4][8];
(0   -1/2*f31*f32   0   -1/2*f132   0   0   0   1/2*f32)
> M := LieAlgebra<CoefficientRing(L), 8 | MT>;
> M;
Lie Algebra of dimension 8 with base ring Polynomial ring of rank 4 
over Rational Field
> M.4*M.8;
(0   -1/2*f31*f32   0   -1/2*f132   0   0   0   1/2*f32)
> M.1*(M.1*M.2);
(f21   0   0   0   0   0   0   0)

    Rep: MonStgElt                      Default: "Auto"

    Check: BoolElt                      Default: true

    Rep: MonStgElt                      Default: "Auto"

    Check: BoolElt                      Default: true

> L := ExtremalLieAlgebra(Rationals(), 3);
> MultiplicationTable(~L);
> L:Maximal;
Lie algebra generated by 3 extremal elements, originally defined over 
Rational Field
  Now living over Polynomial ring of rank 4 over Rational Field
  Dimension: 8
  Picked 4 f-values:
    f(2, [1]) = f21
    f(3, [1]) = f31
    f(3, [2]) = f32
    f(1, [32]) = f132

> M := Instance(L); M;
Lie Algebra of dimension 8 with base ring Polynomial ring of rank 4 
over Rational Field
> M.1*(M.1*M.2);
(f21   0   0   0   0   0   0   0)

> N, phi := Instance(L, [Rationals()|1/7,1/5,1/3,1]);
> N;
Lie Algebra of dimension 8 with base ring Rational Field
> SemisimpleType(N);
A2
> N.1*(N.1*N.2);
(1/7   0   0   0   0   0   0   0)
> y := phi(N.2); z := phi(N.3); 
> Parent(y):Minimal;
Free Lie algebra of rank 3 over Rational Field
> (y,(y,z));
-($.2, ($.3, $.2))
> (y,(y,z)) @@ phi;
(  0 1/3   0   0   0   0   0   0)
> (y,(y,z)) @@ phi @ phi;
1/3*$.2

> L := ExtremalLieAlgebra(Rationals(), 4);
> vals, pairs := FreefValues(L);
> vals;
[
    f21,
    f31,
    f41,
    f32,
    f42,
    f43,
    f143,
    f243,
    f142,
    f132,
    f1432,
    f2431
]
> #vals;
12
> pairs;
[ <2, 1>, <3, 1>, <4, 1>, <3, 2>, <4, 2>, <4, 3>, <1, 5>, <2, 5>, <1, 
6>, <1, 8>, <1, 11>, <2, 12> ]

> fValue(L, 1, 5);
f143
> fValue(L, 4, 17);
-f41*f42
> fValueProof(L, 4, 17);
f(4, [241]) -> -f(4,[2])*f(4,[1]) {f(x,[y,[x,N]]) = -f(x,y)f(x,N) by 
  assoc. of f and anti-comm. of L}
    f(4, [2]) = f42 {Free}
    f(4, [1]) = f41 {Free}
= -f41*f42

    NumSamples: RngIntElt               Default: ∞

    Check: BoolElt                      Default: true

    Rep: MonStgElt                      Default: "Auto"

    SetVerbose("AlgLieExtr", n):        Maximum: 10

    Check: BoolElt                      Default: true

> L := ExtremalLieAlgebra(Rationals(), 3);
> FreefValues(L);
[
    f21,
    f31,
    f32,
    f132
]
[ <2, 1>, <3, 1>, <3, 2>, <1, 4> ]

> g := func< | [ Random(GF(5)) : i in [1..4] ]>;
> repeat M := Instance(L, g()); until Rank(KillingForm(M)) eq 8;
> M;
Lie Algebra of dimension 8 with base ring GF(5)
> SemisimpleType(M);
A2

> DimensionsEstimate(L, g : NumSamples := 500);
[ <3, 121, "3.12">, <8, 379, "3.83"> ]
{* 3^^121, 8^^379 *}

> A := InstancesForDimensions(L, g, {3,8} : Check := false);         
> A[3];
<[ 2, 1, 4, 4 ], Lie Algebra of dimension 8 with base ring GF(5), 
Mapping from: Lie Algebra of dimension 8 with base ring GF(5) to Free 
Lie algebra of rank 3 over GF(5) given by a rule>
> M := A[3][2]; MM := M/SolvableRadical(M); MM;
Lie Algebra of dimension 3 with base ring GF(5)
> SemisimpleType(MM);
A1
> M := A[8][2]; IsSimple(M);
true
> SemisimpleType(M);
A2