|
Throughout this section, let Q be a quadratic form of Witt index r on
a vector space V over a finite field F such that the polar form of
Q is non-degenerate and let C denote the Clifford algebra of Q.
The Clifford group of C is
Γ = { s ∈C | s is a unit and s - 1vs ∈V
for all v∈V }
and the vector representation of Γ is the homomorphism
χ : Γ to GL(V) such that for s∈Γ, χ(s) is
the linear transformation sending v∈V to s - 1vs. In fact,
χ(Γ) is a subgroup of the orthogonal group O(V, Q).
Except when the Witt index of Q is 2 and V is a space of dimension
4 over GF(2), if dim V is even, χ(Γ) = O(V, Q) and if
dim V is odd, χ(Γ) = SO(V, Q). (See [Che97] for
further details.)
The matrix of the Clifford group element g∈Γ acting on
the quadratic space V by conjugation.
If v is a non-singular element of V, the negative of the linear
transformation χ(v) is the reflection in the hyperplane orthogonal
to v.
> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C, V, f := CliffordAlgebra(Q);
> v := V![2,0,2,0,0,1];
In order to ensure v is non-singular we check its quadratic norm.
> QuadraticNorm(v);
2
> A := VectorAction(f(v));
> -A eq OrthogonalReflection(v);
true
The special Clifford group is Γ^ + = Γ∩C_ + and
χ(Γ^ + ) = SO(V, Q). If α is the main anti-automorphism
of C, the spin group of Q is
Spin(V, Q) = { s∈Γ^ + | α(s)s = 1 }.
Given the polar form β of Q and linearly independent vectors u, v ∈V
such that u is singular and β(u, v) = 0, the Siegel transformation
defined by u and v (see Chapter POLAR SPACES) is the isometry
ρu, v defined by
x ρu, v = x + β(x, v)u - β(x, u)v - Q(v)β(x, u) u.
In the Clifford algebra of Q, the conditions on u and v become
u2 = 0 and uv + vu = 0. Thus uv - 1∈Spin(V, Q) and
χ(uv - 1) = ρu, v. Except for Ω^ + (4, 2) the group
Ω(V, Q) is generated by Siegel transformations and thus
χ :Spin(V, Q) to Ω(V, Q) is onto; its kernel is {∓ 1}.
Regarding Ω(V, Q) as a group of Lie type, the subgroups
Xu, v = < ρtu, v | t ∈F > are root groups.
(If dim V = 2r, we consider only the groups for which both
u and v are singular.) In Magma, the generators of the
groups Ω(V, Q) are defined in terms of root elements (see
[RT98]).
We verify that a Siegel transformation ρ u, v can be obtained as
the vector representation of uv - 1.
> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C, V, f := CliffordAlgebra(Q);
> u := V.1;
> v := V.5;
> VectorAction(f(u)*f(v) - One(C)) eq SiegelTransformation(u,v);
true
When F = GF(q) and dim V = 2r we construct the elements
of Spin(V, Q) which map onto the standard generators of Ω^ + (2r, q).
> q := 3;
> r := 4;
> K := GF(3);
> Q := StandardQuadraticForm(2*r,K);
> C,V,f := CliffordAlgebra(Q);
The root element xαk(t) indexed by the kth simple
root is given be the following function.
> x := func< k,t |
> k eq 1 select VectorAction(f(t*V.(r+2))*f(V.(r+1))-One(C))
> else VectorAction(f(t*V.(r-k+2))*f(V.(r+k))-One(C)) >;
It turns out that our choice of Q ensures that the matrices of
the negative root elements are the transposed matrices of the corresponding
positive roots.
> n := func< k, t | x(k,t)*Transpose(x(k,-t^-1))*x(k,t) >;
> h := func< k, t | n(k,t)*n(k,-1) >;
> w := n(1,1)*n(2,1)*n(3,1)*n(4,1);
> xi := PrimitiveElement(K);
> G := OmegaPlus(2*r,q);
> G.1 eq h(2,xi);
true
> G.2 eq Transpose(x(1,1))*x(3,1)*w;
true
Note that the vector representation of Spin(V, Q) is not faithful.
> VectorAction(-One(C)) eq IdentityMatrix(K,2*r);
true
If the dimension of V is 2r, the Clifford algebra C of Q is simple
and hence all irreducible representations are equivalent. We may take the
representation space to be a minimal right ideal S of C. The elements
of S are spinors and the representation itself is the
spin representation. The restrictions of this representation to the
groups Γ, Γ^ + and Spin(V, Q) are also called spin
representations. The spin representation of Γ is irreducible
except when the field has order 2, r = 1 and the Witt index is 1.
The matrix representing the action of s on the right ideal S of
an associative algebra A and s is an element of A.
> F := GF(5);
> Q := StandardQuadraticForm(4,F);
> C,V,f := CliffordAlgebra(Q);
> E, h := EvenSubalgebra(C);
> IsSimple(E);
false
> S := MinimalRightIdeals(E)[1];
> s := (f(V.1+V.4)*f(V.2+V.3))@@h;
> ActionMatrix(S,s);
[0 4]
[1 0]
The Magma functions Spin, SpinPlus and SpinMinus
construct the groups using highest weight representations of the
corresponding group of Lie type. But in this example we construct
the spin representation of Spin^ + (8, 3) by working directly with the
Clifford algebra.
> q := 3;
> r := 4;
> K := GF(3);
> Q := StandardQuadraticForm(2*r,K);
> C,V,f := CliffordAlgebra(Q);
We adapt the code from Example H97E12.
The root element xαk(t) indexed by the kth simple
root is given be the Magma function x(k,t) and the
corresponding negative root element is y(k,t).
> x := func< k,t |
> k eq 1 select f(t*V.(r+2))*f(V.(r+1))-One(C)
> else f(t*V.(r-k+2))*f(V.(r+k))-One(C) >;
> y := func< k,t |
> k eq 1 select f(t*V.r)*f(V.(r-1))-One(C)
> else f(t*V.(r-k+1))*f(V.(r+k-1))-One(C) >;
The other functions are the same as before.
> n := func< k, t | x(k,t)*y(k,-t^-1)*x(k,t) >;
> h := func< k, t | n(k,t)*n(k,-1) >;
> w := n(1,1)*n(2,1)*n(3,1)*n(4,1);
The spin representation space is a minimal right ideal of
the Clifford algebra.
> S := MinimalRightIdeals(C : Limit := 1)[1];
> Dimension(S);
16
> X := sub<GL(16,K) | ActionMatrix(S,h(2,2)), ActionMatrix(S,y(1,1)*x(3,1)*w) >;
> LieType(X,3);
true <"D", 4, 3>
> LMGOrder(X);
19808719257600
> Z := LMGCentre(X);
> #Z, IsElementaryAbelian(Z);
4 true
> SS := SpinPlus(8,K);
> #SS;
19808719257600
The spin representation of Spin^ + (8, 3) is the direct sum of two
half spin representations, neither of which is faithful. The
half spin spaces are minimal ideals of the even subalgebra of C.
> E, phi := EvenSubalgebra(C);
> T := MinimalRightIdeals(E : Limit := 1)[1];
> Dimension(T);
8
> Y := sub<GL(8,K) | ActionMatrix(T,h(2,2)@@phi),
> ActionMatrix(T,(y(1,1)*x(3,1)*w)@@phi) >;
> LieType(Y,3);
true <"D", 4, 3>
> LMGOrder(Y);
9904359628800
[Next][Prev] [Right] [Left] [Up] [Index] [Root]
|