There is a special type for the basic algebras which are the
modular group algebras of p-groups for p a prime. If G
is a finite p and k is a field of characteristic p, then
the commands BasicAlgebra(G, k) and BasicAlgebra(G) automatically create a basic algebra of
type AlgBasGrpP. The type is optimized for the
computation of cohomology rings. Included for this type are
restriction and inflation maps. Most of the functions for modules
and complexes are the same as for general basic algebras.
We create the cohomology ring of a group G of order 64 and find a
cyclic subgroup Z of the center of G. We compute the restriction
of the cohomology of G to the cohomology of Z and also the inflation
of the cohomology of G/Z to the cohomology ring of G.
> SetSeed(1);
> G := SmallGroup(64,7);
> Z := sub<G| Random(Center(G))>;
> G;
GrpPC : G of order 64 = 2^6
PC-Relations:
G.1^2 = G.4,
G.2^2 = G.5,
G.3^2 = G.5,
G.4^2 = G.6,
G.2^G.1 = G.2 * G.3,
G.3^G.1 = G.3 * G.5,
G.3^G.2 = G.3 * G.5
> #Z, [G!Z.i: i in [1 .. Ngens(Z)]];
4 [ G.4 ]
So we see that Z has order 4 and is generated by the element G.4.
Now construct the quotient and the basic Algebras.
> Q, mu := quo<G|Z>;
> A := BasicAlgebra(G);
> B := BasicAlgebra(Q);
> C := BasicAlgebra(Z);
Next we want the simple modules and the cohomology rings. We compute
the cohomology out to 17 steps which should be more than enough to
get the generators and relations.
> k := SimpleModule(A,1);
> kk := SimpleModule(B,1);
> kkk := SimpleModule(C,1);
> time R := CohomologyRing(k,17);
Time: 2.060
> time S := CohomologyRing(kk,17);
Time: 0.140
> time T := CohomologyRing(kkk,17);
Time: 0.060
The structure of the cohomology rings can be read from the following outputs.
> R`RelationsIdeal,S`RelationsIdeal,T`RelationsIdeal;
First the cohomology ring for $G$.
Ideal of Graded Polynomial ring of rank 6 over GF(2)
Lexicographical Order
Variables: $.1, $.2, $.3, $.4, $.5, $.6
Variable weights: 1 1 2 2 3 4
Basis:
[
$.1^2,
$.1*$.2,
$.2^3,
$.1*$.3,
$.2*$.5,
$.3^2,
$.1*$.5 + $.2^2*$.3,
$.3*$.5,
$.5^2
]
Now the cohomology ring for Q.
Ideal of Graded Polynomial ring of rank 4 over GF(2)
Lexicographical Order
Variables: $.1, $.2, $.3, $.4
Variable weights: 1 1 3 4
Basis:
[
$.1*$.2,
$.1^3,
$.1*$.3,
$.2^2*$.4 + $.3^2
]
And finally the cohomology ring for Z.
Ideal of Graded Polynomial ring of rank 2 over GF(2)
Lexicographical Order
Variables: $.1, $.2
Variable weights: 1 2
Basis:
[
$.1^2
]
Next we require the inputs for the restriction and inflation maps.
> Pr1 := k`CompactProjectiveResolution;
> Pr2 := kk`CompactProjectiveResolution;
> Pr3 := kkk`CompactProjectiveResolution;
> Ac1 := k`AllCompactChainMaps;
> Ac2 := kk`AllCompactChainMaps;
> Ac3 := kkk`AllCompactChainMaps;
Now the inflation map from Q to G sends the generators of the
cohomology of Q to the given list of elements in the cohomology
ring of G.
> inf := InflationMap(Pr2,Pr1,Ac2,Ac1,R,mu);
> inf;
[
$.2,
$.1,
$.5,
$.6
]
The restriction map from the cohomology ring of G to the cohomology
ring of Z sends the generators of R to the corresponding elements
in the computed sequence.
> res := RestrictionOfGenerators(Pr1,Pr3,Ac1,Ac3,T);
> res;
[
0,
0,
0,
$.2,
0,
0
]
Finally, a set of minimal relations is determined for the cohomology ring R.
> MinimalRelations(R);
[
$.1^2,
$.1*$.2,
$.2^3,
$.1*$.3,
$.2*$.5,
$.3^2,
$.1*$.5 + $.2^2*$.3,
$.3*$.5,
$.5^2
]
[Next][Prev] [Right] [Left] [Up] [Index] [Root]