Automorphisms

BarAutomorphism(U) : AlgQUE -> Map

For a quantized enveloping algebra U this returns the bar-automorphism of U (Section Quantized Enveloping Algebras). The map returned by this function has its inverse stored, which can be retrieved using Inverse.

AutomorphismOmega(U) : AlgQUE -> Map

For a quantized enveloping algebra U this returns the automorphism of U that is denoted by ω (Section Quantized Enveloping Algebras). The map returned by this function has its inverse stored, which can be retrieved using Inverse.

AntiAutomorphismTau(U) : AlgQUE -> Map

For a quantized enveloping algebra U this returns the anti-automorphism of U that is denoted by τ (Section Quantized Enveloping Algebras). The map returned by this function has its inverse stored, which can be retrieved using Inverse.

AutomorphismTalpha(U, k) : AlgQUE, RngIntElt -> Map

Let U be a quantized enveloping algebra, and let k be an integer between 1 and the rank of the root datum. Then this function returns the automorphism T_αk of U, corresponding to the k-th simple root (Section PBW-type Bases). The map returned by this function has its inverse stored, which can be retrieved using Inverse.

DiagramAutomorphism(U, p) : AlgQUE, GrpPermElt -> Map

GraphAutomorphism(U, p) : AlgQUE, GrpPermElt -> Map

Let U be a quantized enveloping algebra, and let p be a permutation of { 1, ..., r}, where r is the rank of the root datum. Here p must represent a diagram automorphism of the root datum (i.e., it leaves the Dynkin diagram invariant). Then this function returns the corresponding automorphism of U (see Section Quantized Enveloping Algebras). The map returned by this function has its inverse stored, which can be retrieved using Inverse.

Example AlgQEA_QGrpAutoms (H112E9)

> R:= RootDatum("G2");
> U:= QuantizedUEA(R);
> b:= BarAutomorphism(U);
> b(U.3);
(q^10 - q^6 - q^4 + 1)/q^4*F_1^(2)*F_6 + (q^4 - 1)/q^2*F_1*F_5 + F_3

A known result states that T_αr ^{- 1} = τ T_αr τ. We check that for the quantum group of type C₃, and the third simple root.

> U:= QuantizedUEA(RootDatum("C3"));
> t:= AntiAutomorphismTau(U);
> T:= AutomorphismTalpha(U, 3);
> Ti:= Inverse(T);
> f:= t*T*t;         
> &and[ Ti(U.i) eq f(U.i) : i in [1..21] ];
true

A diagram automorphism maps the canonical basis into itself. We check that for the set of elements of the canonical basis of the quantized enveloping algebra of type D₄ of weight α₁ + 3α₂ + 2α₃ + 2α₄. (Here α_i is the i-th simple root.) The chosen diagram automorphism maps this weight to 2α₁ + 3α₂ + α₃ + 2α₄. Therefore we also compute the elements of the canonical basis of that weight.

> U:= QuantizedUEA(RootDatum("D4"));
> p:= SymmetricGroup(4)!(1,3,4);    
> d:= DiagramAutomorphism(U, p);
> e1:= CanonicalElements(U, [1,3,2,2]);
> e2:= CanonicalElements(U, [2,3,1,2]);
> &and[ d(x) in e2 : x in e1 ];
true

---

[Next][Prev] [Right] [Left] [Up] [Index] [Root]